Funkcja ReadKey

Składnia: znak:=ReadKey;

Jest to funkcja, która znajduje się w bibliotece CRT i zwraca znak odczytany z klawiatury ( nie cały ciąg znaków STRING a tylko jeden typu CHAR ). np.

USES CRT;

Var
  znak:char;

Begin
  WriteLn( 'Wcisnij jakis klawisz...');
  znak:=ReadKey;
  WriteLn( 'Wcisniety zostal klawisz: ',znak );
End.

Funkcja Chr

Składnia:
znak:=Chr(liczba);
znak:=#liczba;

Każdy litera, cyfra czy inny znak (np. ramki) posiadają swój własny numer (dokładniej jest to liczba od 0 do 255) i jest odczytywany z tablicy kodów ASCII, np. znakowi 'A' odpowiada liczba 65, znakowi 'a' liczba 97, a znakowi '2' liczba 50. Aby można było zamieniać liczbę na znak używa się właśnie funkcji Chr, która zwraca znak typu CHAR np.

Begin
 WriteLn(chr(70));
 WriteLn(chr(43));
 WriteLn(#43);
 WriteLn(chr(39));
End.

WriteLn( 'Alfabet Morse'a' );

WriteLn( 'Alfabet Morse'+chr(39)+'a' );

WriteLn( 'Alfabet Morse'+#39+'a' );

WriteLn( 'Alfabet Morse',#39,'a' );

Begin
  WriteLn(chr(7));
End.

USES CRT;

Var
  znak:char;

Begin
  ClrScr;
  WriteLn('Wcisnij klawisz ESC');
  Repeat
    znak:=ReadKey;
  Until znak=Chr(27);
End.

Funkcja Ord

Składnia: liczba:=Ord(znak);

Ta funkcja jest podobna do funkcji Chr, tylko że w niej zamieniane jest na odwrót, nie liczby na znaki, tylko znaki na liczby :) np. ord('A')=65 ord('a')=97 ord('2')=50 itd. np.

USES CRT;

Var
  znak:char;

Begin
  Repeat
    znak:=ReadKey;
    WriteLn(znak,'   ',ord(znak));
  Until znak=Chr(27);
End.

Obsługa Klawiszy Rozszerzonych

Klawisze rozszerzone podobnie jak zwykłe odczytuje się funkcją ReadKey. Jest jednak jedna różnica, jeżeli to jest klawisz rozszerzony to funkcja ReadKey zwróci nam wartość chr(0), aby rozpoznać który to klawisz z rozszerzonych, to należy POWTÓRNIE ODCZYTAĆ KLAWISZ funkcją ReadKey. Aby to objaśnić obejrzyj przykład:

USES CRT;

Var
  normalny,rozszerzony:char;

Begin
  WriteLn( 'Wcisnij jakis klawisz...');
  normalny:=ReadKey;
  if normalny=chr(0) then
    Begin
      rozszerzony:=ReadKey;
      WriteLn( 'Wcisniety zostal rozszerzony klawisz: ',rozszerzony );
    End Else WriteLn( 'Wcisniety zostal klawisz: ',normalny );
End.

USES CRT;

Var
  c1,c2:char;

Begin
  Repeat
  c1:=ReadKey;
  c2:=' ';                                              {1}
  if c1=chr(0) then c2:=ReadKey;                        {2}
  if c2='H' then WriteLn('Kursor w górę');
  if c2='P' then WriteLn('Kursor w dół');
  if c2='M' then WriteLn('Kursor w prawo');
  if c2='K' then WriteLn('Kursor w lewo');
  Until c1=chr(27);
End.

Procedura Inc

Procedura Dec

Menu w trybie tekstowym sterowane kursorami

Na początek zrobimy menu z trzema opcjami wyboru, używając tu tablice bo bez nich byłoby ciężko, będzie to trochę większy program od tych co robiliśmy do tej pory ale mam nadzieję że sobie poradzisz :)

USES CRT;
Var
 c1,c2:char;
 y:byte;
 tablica:array[1..3]of string;

Procedure info;                                {1}
Begin
End;

Procedure glowny_program;                      {2}
Begin
End;

Begin
  Tablica[1]:='   Info    ';                   {3}
  Tablica[2]:='  Program  ';                   {4}
  Tablica[3]:='  Wyjscie  ';                   {5}
  ClrScr;
  TextColor(15);
  For y:=1 to 3 do                             {6}
    Begin                                      {7}
      TextColor(15);                           {8}
      TextBackGround(0);                       {9}
      GotoXY(32,11+y);                         {10}
      Write(tablica[y]);                       {11}
    End;                                       {12}
  y:=1;                                        {13}
  Repeat                                       {14}
    TextColor(0);                              {15}
    TextBackGround(15);                        {16}
    GotoXY(32,11+y);                           {17}
    Write(tablica[y]);                         {18}
    c1:=ReadKey;                               {19}
    c2:=' ';                                   {20}
    If c1=Chr(0) Then c2:=ReadKey;             {21}
    TextColor(15);                             {22}
    TextBackGround(0);                         {23}
    GotoXY(32,11+y);                           {24}
    Write(tablica[y]);                         {25}
    If c2='H' Then Dec(y);                     {26}
    If c2='P' Then Inc(y);                     {27}
    If y=0 Then y:=3;                          {28}
    If y=4 Then y:=1;                          {29}
    If c1=Chr(27) Then y:=3;                   {30}
  Until (c1=chr(27)) or (c1=chr(13));          {31}
  If y=1 Then info;                            {32}
  If y=2 Then glowny_program;                  {33}
End.

USES CRT;
Var
 c1,c2:char;
 y:byte;
 tablica:array[1..3]of string;

Procedure info;
Begin
End;

Procedure glowny_program;
Begin
End;

Procedure wyswietl(ktory,kolor,tlo:byte);      {1}
Begin
  TextColor(kolor);                            {2}
  TextBackGround(tlo);                         {3}
  GotoXY(32,11+ktory);                         {4}
  Write(tablica[ktory]);                       {5}
End;

Begin
  Tablica[1]:='   Info    ';
  Tablica[2]:='  Program  ';
  Tablica[3]:='  Wyjscie  ';
  ClrScr;
  For y:=1 To 3 Do wyswietl(y,15,0);           {6}
  y:=1;
  Repeat
    wyswietl(y,0,15);                          {7}
    c1:=ReadKey;
    c2:=' ';
    If c1=chr(0) Then c2:=ReadKey;
    wyswietl(y,15,0);                          {8}
    If c2='H' Then Dec(y);
    If c2='P' Then Inc(y);
    If y=0 Then y:=3;
    If y=4 Then y:=1;
    If c1=chr(27) Then y:=3;
  Until (c1=chr(27)) or (c1=chr(13));
  If y=1 Then info;
  If y=2 Then glowny_program;
End.